TextField.StyleSheet.getStyle()

Доступность

Flash Player 7.

Синтаксис

styleSheet.getStyle(styleName:String) : Object

Параметры

styleName Строка, определяющая имя стиля который необходимо возвратить.

Возвращает

Некоторый объект.

Описание

Метод; возвращает копию объекта таблицы стилей, имеющий стиль с именем styleName. Если не имеется никакого объекта, связанного с styleName, возвращается null.

Пример

В следующем примере загружаются стили в файле CSS, разбирается таблица стилей и выводится в Output панели имена стилей и значения свойств. Создайте ActionScript файл с именем StyleSheetTracer.as и введите следующий код :

import TextField.StyleSheet;
class StyleSheetTracer {
  // StyleSheetTracer.displayFromURL
  //
  // Это метод выведения таблицы стилей CSS в
  // URL "url" в панели Output.
  static function displayFromURL(url:String):Void {
    // Создаём объект таблицы стилей
    var my_styleSheet:StyleSheet = new StyleSheet();
    // Операция загрузки является асинхронной, настроим
    // вызов функции вывода окончания загрузки таблицы стилей.
    my_styleSheet.onLoad = function(success:Boolean) {
      if (success) {
        StyleSheetTracer.display(this);
      } else {
        trace("Error loading style sheet "+url);
      }
    };
    // Начало операции загрузки.
    my_styleSheet.load(url);
  }
  static function display(my_styleSheet:StyleSheet):Void {
    var styleNames:Array = my_styleSheet.getStyleNames();
    if (!styleNames.length) {
      trace("This is an empty style sheet.");
    } else {
      for (var i = 0; i<styleNames.length; i++) {
        var styleName:String = styleNames[i];
        trace("Style "+styleName+":");
        var styleObject:Object = my_styleSheet.getStyle(styleName);
        for (var propName in styleObject) {
          var propValue = styleObject[propName];
          trace("\t"+propName+": "+propValue);
        }
        trace("");
      }
    }
  }
}

Создайте новый CSS файл, именованный styles.css, который имеет два стиля с именами .heading и .mainBody , которые определяют свойства для font-family, font-size и font-weight. Введите следующий код :

/* В styles.css */
.heading {
  font-family: Arial, Helvetica, sans-serif;
  font-size: 24px;
  font-weight: bold;
}
.mainBody {
  font-family: Arial, Helvetica, sans-serif;
  font-size: 12px;
  font-weight: normal;
}

Наконец, в файле FLA или AS, введите следующий код ActionScript для загрузки внешней таблицы стилей, styles.css.

StyleSheetTracer.displayFromURL("styles.css");
// Это выводится в панели Output:
Style .heading:
  fontWeight: bold
  fontSize: 24px
  fontFamily: Arial, Helvetica, sans-serif

Style .mainBody:
  fontWeight: normal
  fontSize: 12px
  fontFamily: Arial, Helvetica, sans-serif

См.также

TextField.StyleSheet.setStyle()

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление